home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Monster Media 1996 #15
/
Monster Media Number 15 (Monster Media)(July 1996).ISO
/
pcboard
/
makeup1.zip
/
MAKEUP.PPS
< prev
next >
Wrap
Text File
|
1996-03-26
|
10KB
|
186 lines
;-----------------------------------------------------------------------------
;| |
;| MAKEUP.PPE v1.0 |
;| PCBOARD 15.0+ Force address update on login |
;| Atlantis Software |
;| Atlantis BBS 706-776-9276 |
;| |
;-----------------------------------------------------------------------------
;| Define Variables |
;-----------------------------------------------------------------------------
INTEGER Lp
STRING Menu_Command, Answer, InputChar, Verification_Command
STRING Command_A, Command_B, Command_C, Command_D
STRING Command_E, Command_F, Command_G
;-----------------------------------------------------------------------------
;| Start Program |
;-----------------------------------------------------------------------------
GETUSER
IF ((PSA(2) = 0) & (PSA(3) = 0)) STOP
IF ((STRIP(U_ADDR(0), " ") = "" & (STRIP(U_ADDR(1), " ") = "")) | (STRIP(U_ADDR(2), " ") = "") | (STRIP(U_ADDR(3), " ") = "") | (STRIP(U_ADDR(4), " ") = "") | (STRIP(U_ADDR(5), " ") = "") | (PSA(2) & STRIP(U_VER, " ") = "")) GOTO MAIN_PROGRAM
END
:MAIN_PROGRAM
GOSUB FORMAT_COMMANDS
Menu_Command = ""
PRINTLN "@CLS@@X60@POS:80@@X0F"
PRINTLN "@X60 @X0F Date: @X0E@SYSDATE@@BOARDNAME:45C@@X0FTime: @X0E@SYSTIME@ ET @X60@POS:80@@X0F"
PRINTLN "@X60 @X0F Carrier:@X0E@CARRIER:6R@@X0A Login Interrupt @X0FTime Left:@X0E@MINLEFT:4R@ @X60@POS:80@@X0F"
PRINTLN "@X60@POS:80@@X0F"
NEWLINE
PRINTLN " Your registration is incomplete. Please complete your @X0EAddress Information@X0F."
NEWLINE
PRINTLN " @X0AA @X0FLine 1, Street (Mail) Address @X0AD @X0FProvince or State"
PRINTLN " @X0AB @X0FLine 2, Street (Mail) Address @X0AE @X0FPostal/Zipcode"
PRINTLN " @X0AC @X0FCity, Town or Village @X0AF @X0FCountry, Nation or Region"
IF (PSA(2) <> 0) THEN
PRINTLN " @G @X0FVerification Information @X0AQ @X0FQuit and Save Corrections"
InputChar = "abcdefgqABCDEFGQ"
ELSE
PRINTLN " @X0AQ @X0FQuit and Save Corrections"
InputChar = "abcdefqABCDEFQ"
END IF
PRINTLN " @X06┌───────────────────────────────────────────────────────────┐"
PRINTLN " @X06│ @X0AA @X0F= @X0E" + Command_A + "@POS:70@@X06│"
PRINTLN " @X06│ @X0AB @X0F= @X0E" + Command_B + "@POS:70@@X06│"
PRINTLN " @X06│ @X0AC @X0F= @X0E" + Command_C + "@POS:46@@X0AE @X0F= @X0E" + Command_E + "@POS:70@@X06│"
PRINTLN " @X06│ @X0AD @X0F= @X0E" + Command_D + "@POS:46@@X0AF @X0F= @X0E" + Command_F + "@POS:70@@X06│"
IF (PSA(2) <> 0) THEN
PRINTLN " @X06│ @X0AG @X0F= @X0E" + Command_G + "@POS:46@@X0F<-- WILL NOT ECHO" + "@POS:70@@X06│"
PRINTLN " @X06└───────────────────────────────────────────────────────────┘"
ELSE
PRINTLN " @X06└───────────────────────────────────────────────────────────┘"
END IF
INPUTSTR "@X0FWhich field would you like to revise@X0A", Menu_Command, 0Eh, 1, InputChar, FIELDLEN + GUIDE + UPCASE + LFBEFORE + ERASELINE
IF (Menu_Command = "A") GOSUB USER_ADDR0
IF (Menu_Command = "B") GOSUB USER_ADDR1
IF (Menu_Command = "C") GOSUB USER_ADDR2
IF (Menu_Command = "D") GOSUB USER_ADDR3
IF (Menu_Command = "E") GOSUB USER_ADDR4
IF (Menu_Command = "F") GOSUB USER_ADDR5
IF (Menu_Command = "G" & PSA(2)) GOSUB USER_VERIFICATION
IF (Menu_Command = "Q") GOTO END_PROGRAM
IF (Menu_Command = "") GOTO END_PROGRAM
GOTO MAIN_PROGRAM
:FORMAT_COMMANDS
LET Command_A = LEFT(RTRIM(U_ADDR(0), CHR(32)) + "·················································", 49)
LET Command_B = LEFT(RTRIM(U_ADDR(1), CHR(32)) + "·················································", 49)
LET Command_C = LEFT(RTRIM(U_ADDR(2), CHR(32)) + "·························", 25)
LET Command_D = LEFT(RTRIM(U_ADDR(3), CHR(32)) + "·························", 25)
LET Command_E = LEFT(RTRIM(U_ADDR(4), CHR(32)) + "···············", 15)
LET Command_F = LEFT(RTRIM(U_ADDR(5), CHR(32)) + "···············", 15)
LET Command_G = LEFT(RTRIM(U_VER, CHR(32)) + "·························", 25)
FOR Lp = 1 TO (LEN(U_VER))
Command_G = REPLACE(Command_G, MID(Command_G, Lp, 1), "*")
NEXT
RETURN
:USER_ADDR0
IF (EXIST(PPEPATH() + "makeupA")) DISPFILE PPEPATH() + "makeupA", LANG + SEC + GRAPH
INPUTSTR "@X0FLine 1, Street (Mail) Address@X0A", U_ADDR(0), 0Eh, 50, MASK_ALPHA() + MASK_NUM() + MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE
RETURN
:USER_ADDR1
IF (EXIST(PPEPATH() + "makeupB")) DISPFILE PPEPATH() + "makeupB", LANG + SEC + GRAPH
INPUTSTR "@X0FLine 2, Street (Mail) Address@X0A", U_ADDR(1), 0Eh, 50, MASK_ALPHA() + MASK_NUM() + MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE
RETURN
:USER_ADDR2
IF (EXIST(PPEPATH() + "makeupC")) DISPFILE PPEPATH() + "makeupC", LANG + SEC + GRAPH
INPUTSTR "@X0FCity, Town or Village@X0A", U_ADDR(2), 0Eh, 25, MASK_ALPHA() + MASK_NUM() + MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE
RETURN
:USER_ADDR3
IF (EXIST(PPEPATH() + "makeupD")) DISPFILE PPEPATH() + "makeupD", LANG + SEC + GRAPH
INPUTSTR "@X0FProvince or State@X0A", U_ADDR(3), 0Eh, 10, MASK_ALPHA() + MASK_NUM() + MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE
RETURN
:USER_ADDR4
IF (EXIST(PPEPATH() + "makeupE")) DISPFILE PPEPATH() + "makeupE", LANG + SEC + GRAPH
INPUTSTR "@X0FPostal/Zipcode@X0A", U_ADDR(4), 0Eh, 10, MASK_ALPHA() + MASK_NUM() + MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE
RETURN
:USER_ADDR5
IF (EXIST(PPEPATH() + "makeupF")) DISPFILE PPEPATH() + "makeupF", LANG + SEC + GRAPH
INPUTSTR "@X0FCountry, Nation or Region@X0A", U_ADDR(5), 0Eh, 15, MASK_ALPHA() + MASK_NUM() + MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE
RETURN
:USER_VERIFICATION
IF (REPLACE(TRIM(STRIP(U_VER, CHR(255)), " "), CHR(255), " ") <> "") THEN
NEWLINE
PRINTLN " @X0EIf you need to change or alter this field, you must first enter"
PRINTLN " the information exactly like it was first entered."
PROMPTSTR 707, Verification_Command, 25, MASK_ALPHA() + MASK_NUM() + MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE + LFAFTER + NEWLINE
IF (Verification_Command = U_VER) THEN
IF (EXIST(PPEPATH() + "makeupG")) DISPFILE PPEPATH() + "makeupG", LANG + SEC + GRAPH
PROMPTSTR 706, U_VER, 25, MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE + LFAFTER
ELSE
IF (Verification_Command <> "") THEN
PRINTLN " @X0FSorry, the User Verification Information you just entered, does"
PRINTLN " @X0ENOT @X0Fmatch the information you previuosly entered."
NEWLINE
WAIT
END IF
END IF
ELSEIF (REPLACE(TRIM(STRIP(U_VER, CHR(255)), " "), CHR(255), " ") = "") THEN
IF (EXIST(PPEPATH() + "makeupG")) DISPFILE PPEPATH() + "makeupG", LANG + SEC + GRAPH
PROMPTSTR 706, U_VER, 25, MASK_ASCII(), FIELDLEN + GUIDE + UPCASE + LFBEFORE
END IF
RETURN
:END_PROGRAM
IF ((STRIP(U_ADDR(0), " ") = "" & (STRIP(U_ADDR(1), " ") = "")) | (STRIP(U_ADDR(2), " ") = "") | (STRIP(U_ADDR(3), " ") = "") | (STRIP(U_ADDR(4), " ") = "") | (STRIP(U_ADDR(5), " ") = "") | (PSA(2) & STRIP(U_VER, " ") = "")) GOTO NO_USER_INFO
CLS
NEWLINE
PRINTLN " @X0FThanks for taking the time to complete your registration."
PRINTLN " This information will enable us to automate the completion of order forms"
PRINTLN " and other registrations that you may select while online."
PRINTLN
PRINTLN " If you need to update your address information in the future,"
PRINTLN " go to the @X0EUSER @X0FMenu and select ""@X0AW@X0F""."
NEWLINE
LOG "User updated his address information via MAKEUP.PPE", 0
DISPTEXT 273, LFAFTER + BELL
NEWLINE
PUTUSER
WAIT
END
:NO_USER_INFO
Answer = (UPPER(NOCHAR()))
CLS
NEWLINE
PRINTLN " @X0EThe following fields are still empty and need to filled:"
NEWLINE
IF ((STRIP(U_ADDR(0), " ") = "") & (STRIP(U_ADDR(1), " ") = "")) PRINTLN " @X0AA@X0F @X0FLine 1, Street (Mail) Address"
IF (STRIP(U_ADDR(2), " ") = "") PRINTLN " @X0AC@X0F City, Town or Village"
IF (STRIP(U_ADDR(3), " ") = "") PRINTLN " @X0AD@X0F Province or State"
IF (STRIP(U_ADDR(4), " ") = "") PRINTLN " @X0AE@X0F Postal/Zipcode"
IF (STRIP(U_ADDR(5), " ") = "") PRINTLN " @X0AF@X0F Country, Nation or Region"
IF ((PSA(2)) & (STRIP(U_VER, " ") = "")) PRINTLN " @X0AG@X0F Verification Information"
NEWLINE
PRINTLN " @X0FWe apologize for the inconvenience, but"
PRINTLN " you @X0EMUST @X0Fprovide the above information in order to continue."
NEWLINE
INPUTYN "@X0FWould you rather logoff (@X0Ay@X0F/@X0AN@X0F)@X0A", Answer, 0Ah
IF (UPPER(LEFT(Answer, 1)) = YESCHAR()) THEN
LOG "User refused to complete registration with address info via MAKEUP.PPE.", 0
GOTO SEEYA_LATER
END IF
GOTO MAIN_PROGRAM
:SEEYA_LATER
PUTUSER
BYE
END